Visual Basic - operatii cu interfata WinXP

Va rog, daca stiti si vreti sa ma ajutati, ati putea sa-mi spuneti citeva chichite legate de Visual Basic:

1_Cum "ma leg" de sunetul (reglarea volumului) din Windows ?
Stiu si pot sa incarc (folosind controlul ActiveX: MMControl) de exp. un fisier MP3 intr-un Program V. Basic dar NU STIU prin ce functie, metoda pot controla volumul fisierului (melodiei).
(folosind controlul ActiveX: MMControl stiti cum pot incarca melodiile in playlist-ul controlului ?)
2_Tot intr-un program V.Basic am creat facilitatea de a STERGE directoare sau fisiere, faza ca se STERG DEFINITIV; as prefera mutare (transfer) in Recycle Bin=WindowsXP - imi trebuie Calea (path-ul) pt Recycle Bin.
Care e calea (path-ul) lui Recycle Bin?

PentiumSEX, on Jun 13 2006, 20:12, said:

foloseste waveOutSetVolume

Private Declare Function waveOutSetVolume Lib "winmm.dll" (ByVal uDeviceID As Long, ByVal dwVolume As Long) As Long

(MMControl-ul nu are playlist, playlistul il faci tu ca nu e decat o lista de fisiere )

PentiumSEX, on Jun 13 2006, 20:12, said:

Cum faci stergerea cu DeleteFile ?
foloseste:SHFileOperation
uite asa:

Private Type SHFILEOPTSTRUCT
  hWnd As Long
  wFunc As Long
  pFrom As String
  pTo As String
  fFlags As Integer
  fAnyOperationsAborted As Long
  hNameMappings As Long
  lpszProgressTitle As Long
End Type

Private Declare Function SHFileOperation Lib "Shell32.dll" _
  Alias "SHFileOperationA" (lpFileOp As SHFILEOPTSTRUCT) As Long
  
Private Const FO_DELETE = &H3
Private Const FOF_ALLOWUNDO = &H40

Public Sub DeleteFileToRecycleBin(Filename As String)
Dim fop As SHFILEOPTSTRUCT

With fop
  .wFunc = FO_DELETE
  .pFrom = Filename
  .fFlags = FOF_ALLOWUNDO
End With

SHFileOperation fop

End Sub

Multumesc OMULE; nu prea am timp acum, cam 10 zile ma tirez din oras, insa o sa revin; pina atunci:

1_Tocmai pt ca nu stiam cum sa reglez volumul la controlul ActiveX - MMControl am folosit in program WindowsMediaPlayer10.
Ei bine pt. WindowsMediaPlayer10 ma intrebam cum as putea lucra cu playlist-ul acestui control. (evident ca o lista cu fisierele MP3 nu era o chestie - eu m-am exprimat neclar; ma gindeam la playlist-ul WindowsMediaPlayer10)
2_Cu siguranta esti "pe felie" si folosirea functiei SHFileOperation ma va ajuta sa "nu ucid definitiv" fisierele.

Inca o data MULTUMESC si, o sa mai revin.

Revenirea, cu doua chestii la care rog ajutor

1_functia "SHFileOperation" vreau sa-mi afiseze MODAL caseta de dialog de confirmare a stergerii; asta pt ca, daca nu confirm stergerea prin apasarea YES\NO pot sa INCHID programul (sau sa efectuez alte operatii) si NU VREAU asta, NU vreau sa ma lase caseta CONFIRAMRE STERGERE.
Pe scurt vreu sa fie afisata vbMODAL caseta.

2_Cum folosesc functia (API din Windows) astfel incit sa trimit in Recycle Bin SIMULTAN mai mute fisiere?
M-a ajutat a-mi spune cum functia "SHFileOperation" trimite (sterge) in Recycle Bin O SINGURA selectie (fisier),
spune-mi te rog, daca sti, cum setez variabila "Private Type SHFILEOPTSTRUCT" astfel incit
functia "SHFileOperation" sa-mi stearga toate fisierele/directoarele selectate; astfel incit
sa pot sterge (DELETE) alegint: YES to ALL (toate selectiile)   sau  YES (doar selectia curenta) ; respectiv NO to ALL   si   NO

_________astept ajutorul POPORULUI, va rog

PentiumSEX, on Jul 20 2006, 19:38, said:

Pentru a afisa fereastrele de confirmare modal seteaza hWnd-ul variabilei SHFILEOPTSTRUCT cu handle-ul ferestrei tale (ex fop.hWnd=Form1.hWnd)

PentiumSEX, on Jul 20 2006, 19:38, said:

Pentru a seta mai multe fisiere bufferul  .pFrom va contine lista de fisiere despartite printr-un null (vbNullChar) iar sfarsitul bufferului va fi terminat cu dublu null.

cam asa va arata functia pentru a rezolva pct-ul 1 si 2:

Public Sub DeleteFilesToRecycleBin(sFileArray() As String, MainWindow As Long)
  
  Dim fop As SHFILEOPTSTRUCT
  Dim cnt As Long
  Dim sFiles As String
 
  'construim un string cu fisierele din array, separate cu null-uri
   For cnt = LBound(sFileArray) To UBound(sFileArray)
	  sFiles = sFiles & sFileArray(cnt) & vbNullChar
   Next

  'adugam null-ul final (vezi msdn: Each file name must be terminated by a single NULL character. 
  ' An additional NULL character must be appended to the end of the final name to indicate the end of pFrom.)
  
 sFiles = sFiles & vbNullChar
   
  With fop
   .wFunc = FO_DELETE
   .pFrom = sFiles
   .fFlags = FOF_ALLOWUNDO
   .hWnd = MainWindow  'extras din msdn: Window handle to the dialog box to display information about the status of the file operation.
  End With

  SHFileOperation fop

End Sub

Cam asa o folosesti daca ai pe Form un DirListBox si un warez_spamBox :

Private Sub Command1_Click()

   Dim fNames() As String
   Dim fPath As String
   Dim c As Long

  'calea folder-ului
   fPath = Dir1.Path
 
  'construim array-ul cu fisierele selectate
   For cnt = 0 To File1.ListCount - 1
	  If File1.Selected(cnt) Then
		 c = c + 1
		 ReDim Preserve fNames(1 To c)
		 fNames(c) = fPath & "\" & File1.List(cnt)
	  End If
   Next
 
  'nimic selectat?
   If c = 0 Then Exit Sub

	DeleteFilesToRecycleBin fNames, Form1.hWnd
 

End Sub

bafta!  

Plecaciune STIMABILE.
Multumesc mult!

PS: Bai frate le sti! Dar nu asta-i minunat, minunat e faptul ca-i ajuti si pe altii cu ceea ce sti.

Noroc si ... mai revin, cine stie.

Cu placere, i'm here to help sper ca vei face si tu acelasi lucru pentru cei care sunt in impas atunci cand timpul iti permite.