Ar trebui sa fie simplu....sau chiar e:)))

Am facut un program cu o baza de date Access...folosesc DataEnvironment pentru a realiza conexiunea la baza de date....si o comanda cu un SQL Statement (ceva de genu SELECT * FROM tabel WHERE ADRESA = "O Adresa"). Apoi un DataReport care sa-mi afisseze datele...
Intrebarea e cum pot sa schimb din cod "SQL Statement"-ul comenzii din  DataEnvironment ????, adica "O Adresa" sa o introduc la momentul executiei..
De exemplu vereau sa selectez adresa dintr-un combo box si sa-mi afiseza datele numai din adresa aia...
"Select * From tablel Where Adresa = " & Combo1.Text
Va multumesc anticipat!!

S9yN37®, on Nov 12 2005, 17:41, said:

Sintaxa SQL este OK cum ai pus-o tu, trebuie doar sa nu uiti ca o conditie de tip text se pune intre ''.
Ex. "SELECT * FROM tablel WHERE Adresa = '" & Combo1.Text & "'"

Pentru numere nu pui nimic iar pentru format date pui ##

bafta!

Yoda, on Nov 17 2005, 20:10, said:

Sar'mana pt help da stiam asta.....ala era doar un exemplu
dar daca tu vrei:
Obiect.Proprietate = "Select * From tablel Where Adresa = " & """" &  Combo1.Text & """"
Dar intrebarea era alta...
cum atribui SQL-ul asta, comenzii aleia din DataEnvironment din cod (la RunTime) ???

iti trimit mai jos o bucata de cod folosita de mine mai demult, am preferat sa o trimit in intregime, chiar dc pare la prima vedere cam rece si poate stufoasa, insa contine destule lucruri care te vor ajuta in lucrul run-time cu rapoartele; de la inceput vreau sa fac precizarea ca DataEnvironment nu este o componenta f reusita in VB (este destul de rigida si uneori chiar imprevizibila) si deci e de preferat sa lucrezi numai cu DataReport in run-time (adica sa-l configurezi in run-time, chiar dc vei scrie mai mult cod)

Private Sub Imprimer()
On Error GoTo ProcError

	Dim rs As ADODB.Recordset
	Dim i As Integer
	Dim aLabel(1 To 19, 1 To 2) As Integer, aTextBox(1 To 19, 1 To 2) As Integer
	
	' lstImp este un control ListBox (pe baza unor item-uri din acest ListBox fac un report); este vorba
	' de niste verbe in franceza care sunt selectate de user
	If lstImpT2.ListCount = 0 Then Exit Sub
	
	'retine pozitiile initiale ale controalelor; aici ai deja acces la controalele de pe DataReport
	' fiecare sectiune are anumite controale pe care le-ai pus in design-time
	With DataReport3.Sections("Section1").Controls
		' retin pozitiile controaleleor pt a le muta ulterior pe DataReport, practic ma joc putin cu aceste 
controale: le mut sau le ascund 
		For i = 1 To 19
			aLabel(i, 1) = .Item("Label" & i).Top
			aLabel(i, 2) = .Item("Label" & i).Left
			
			aTextBox(i, 1) = .Item("text" & i).Top
			aTextBox(i, 2) = .Item("text" & i).Left
		Next i
	End With
	
	'pozitia primului de pe primul rand adica text1 este
	'top=780 si left=432
	
	Set rs = New ADODB.Recordset
	
   ' aici InterogFinal() este o functie care intoarce un recordset, tu aici poti folosi interogarea ta
	rs.Open InterogFinal(), cn, adOpenStatic, adLockOptimistic   
	
	' aici e f important, pui numai DataReport in Designers; poti sa nu folosesti deloc DataEnvironment
	With DataReport3
		Set .DataSource = rs
		.DataMember = ""
		
		With .Sections("Section1").Controls
			For i = 1 To lstImpT2.ListCount
				.Item("text" & i).Visible = True
				' MoveControl este o functie care muta un label in pozitiile retinute de cei 2 vectori 
				MoveControl "text" & i, aTextBox(i, 1), aTextBox(i, 2)
				'aici e important cum se face legatura intre controlul de pe report si un camp din recordset
				.Item("text" & i).DataField = rs.Fields(i).Name
				
				.Item("Label" & i).Visible = True
				MoveControl "Label" & i, aLabel(i, 1), aLabel(i, 2)
				.Item("Label" & i).Caption = lstImpT2.List(i - 1)
			Next i
			
			'mut toate controalele pe primul control(text1) si le fac invisible; astea sunt artificii care poate nu  intereseaza
			For i = lstImpT2.ListCount + 1 To 19
				MoveControl "text" & i, aTextBox(1, 1), aTextBox(1, 2)
				.Item("text" & i).Visible = False
				'adaug fictiv un camp pt a evita eroarea
				.Item("text" & i).DataField = rs.Fields(0).Name
				
				MoveControl "Label" & i, aTextBox(1, 1), aTextBox(1, 2)
				.Item("Label" & i).Visible = False
			Next i
			
			'pt verb
			.Item("Text20").DataField = rs.Fields(0).Name
			
			'diverse setari
			For i = 1 To 19
				.Item("Text" & i).Font.Size = 10
			Next i
			For i = 1 To 19
				.Item("Label" & i).Font.Size = 9
				.Item("Label" & i).Font.Bold = False
				.Item("Label" & i).Font.Italic = True
				'am dat label mai in stanga
				.Item("Label" & i).Left = .Item("Label" & i).Left - 72
			Next i
		End With
		'setari referitoare la imprimanta		
		Printer.PaperSize = vbPRPSA4
		.Sections("Section1").Height = aTextBox(HeightSection1(lstImpT2.ListCount), 1) + 1380
		
		.Orientation = rptOrientLandscape
		.Refresh
		.WindowState = 2
		.Show
	End With
	
	If rs.State = 1 Then rs.Close
	Set rs = Nothing
ProcExit:
	Exit Sub
ProcError:
	If Err.Number = 482 Then
		MsgFr Me, "Timer1", "Il n'y a pas une imprimante.", strA, vbCritical
	Else
		MsgBox Err.Number & vbCrLf & Err.Description
	End If
	Resume ProcExit

End Sub

S9yN37®, on Nov 18 2005, 01:22, said:

Imi pare rau, nu folosesc DataEnviornment, eu lucrez cu ADO connections & recordsets in cod.

Incearca aici:
http://msdn.microsof...entDesigner.asp

Yoda, on Nov 18 2005, 20:48, said:

Da...gasisem si eu tot aici....multzam...

Se scrie in SQL Statement de exemplu asta:

SELECT * FROM tAPA
WHERE ADRESA = tempADR
ORDER BY NUME_PRENUME

iar tempADR devine un parametru in tag-ul "Parameters" din proprietatile comenzii din DataEnvironment...

iar apoi in program:

Dim tempADR as String
tempADR = cmbAdresa.Text
DataEnvironment1.Comanda tempADR 'ASTA CAUTAM!!!


Uite:

Private Sub cmdBalantaP_Click()
Dim tempADR As String
tempADR = cmbAdresa.Text
    If DE1.rstAPA_P.State = adStateOpen Then
        DE1.rstAPA_P.Close
    End If

DE1.tAPA_P tempADR 'Aici!!!

CitesteLunaCurenta
drBalanta_P.Caption = "BALANTA:" & Space(1) & tempADR & "-" & strLuna & strAnul
drBalanta_P.Title = tempADR & Space(1) & "-" & Space(1) & strLuna & Space(1) & strAnul
drBalanta_P.Show
Unload frmBalanta
End Sub